Apexトリガを使ってファイルの作成・更新・削除を制限しよう！

trigger ContentDocumentTrigger on ContentDocument (before update) {

    //ハンドラー
    ContentDocumentTriggerHandler handler = new ContentDocumentTriggerHandler();

    if(Trigger.isBefore && Trigger.isUpdate){
        handler.beforeUpdate(Trigger.newMap);
    }
}

public with sharing class ContentDocumentTriggerHandler {
    public void beforeUpdate(Map<Id, ContentDocument> newCdMap) {

        /*
        概要：
        　更新しようとしているファイルが紐づく商談のフェーズがClosed Lostか判定し、
        　Closed Lostであった場合はエラーを出す
　　　　*/

        //更新対象のContentDocumentに紐づくContentDocumentLinkの取得
        List<ContentDocumentLink> cdlList = new List<ContentDocumentLink>([SELECT Id, ContentDocumentId, linkedEntityId
                                                                            FROM ContentDocumentLink 
                                                                            WHERE ContentDocumentId IN: newCdMap.keySet()]);

        //関連レコード（linkedEntityId）の抽出
        Set<Id> linkedIdSet = new Set<Id>();
        for(ContentDocumentLink cdl: cdlList) {
            linkedIdSet.add(cdl.linkedEntityId);
        }

        //関連レコード（linkedEntityId）の中から商談に紐づくレコードを抽出
        Map<Id, Opportunity> oppMap = new Map<Id, Opportunity>([SELECT Id, StageName 
                                                                FROM Opportunity 
                                                                WHERE Id IN: linkedIdSet]);
        
        for(ContentDocumentLink cdl: cdlList) {

            //関連レコードのID
            Id targetId = cdl.linkedEntityId;
            
            //関連レコードのオブジェクトタイプ
            sObjectType objType = targetId.getSObjectType();
　　　 
            //紐づくContentDocumentレコード
            ContentDocument cd = newCdMap.get(cdl.ContentDocumentId);

            //関連レコードのオブジェクトが商談かどうか、フェーズがClose Lostかどうかを判定
            if(objType == Opportunity.sObjectType && oppMap.get(targetId).StageName == 'Closed Lost'){
                cd.addError('失注した商談のファイルは追加・更新できません。');
            }
        }
    }
}

trigger ContentDocumentLinkTrigger on ContentDocumentLink (before delete) {

    //ハンドラー
    ContentDocumentLinkTriggerHandler handler = new ContentDocumentLinkTriggerHandler();

    if(Trigger.isBefore && Trigger.isDelete){
        handler.beforeDelete(Trigger.oldMap);
    }
}

public with sharing class ContentDocumentLinkTriggerHandler {
    public void beforeDelete(Map<Id, ContentDocumentLink> oldCdlMap) {

        /*
        概要：
        　削除しようとしているファイルが紐づく商談のフェーズがClosed Lostか判定し、
        　Closed Lostであった場合はエラーを出す
　　　　*/

        //関連レコード（linkedEntityId）の抽出
        Set<Id> linkedIdSet = new Set<Id>();
        for(ContentDocumentLink cdl: oldCdlMap.values()) {
            linkedIdSet.add(cdl.linkedEntityId);
        }
        
        //関連レコード（linkedEntityId）の中から商談に紐づくレコードを抽出
        Map<Id, Opportunity> oppMap = new Map<Id, Opportunity>([SELECT Id, StageName 
                                                                FROM Opportunity 
                                                                WHERE Id IN: linkedIdSet]);

        for(ContentDocumentLink cdl: oldCdlMap.values()) {
            
            //関連レコードのID
            Id targetId = cdl.linkedEntityId;

            //ContentDocumentLinkと紐づくレコードのオブジェクトタイプ
            sObjectType objType = targetId.getSObjectType();

            //ファイルを商談から削除
            if(objType == Opportunity.sObjectType && oppMap.get(targetId).StageName == 'Closed Lost'){
                cdl.addError('失注した商談のファイルは削除できません。');
            }
        }
    }
}