LINEChatBotでナレッジを表示してみよう

@RestResource(urlMapping='/line_webhook_callback')
global with sharing class LineWebHookCallback {

    static String LINE_REPLY_URI = 'https://api.line.me/v2/bot/message/reply';
    static String CH_ACCESS_TOKEN = '**環境に合わせて設定**';
    static String MYSITESURL = 'https://**SitesのURL**.force.com/**カスタムURL**/articles/**記事タイプ**/';
 
    @HttpPost
    global static Map<String,String> doPost(){
 
        RestRequest req = RestContext.request;
        RestResponse res = RestContext.response;
          
        Map<String, Object> callbackParams = (Map<String, Object>)JSON.deserializeUntyped(req.requestBody.ToString());
        List<Object> resultParams = (List<Object>)callbackParams.get('events');

        String replyToken = '';
        String messageText = '';
                        
        for (Object obj : resultParams) {
            Map<String, Object> params = (Map<String, Object>)obj;           
            replyToken = (String)params.get('replyToken');
            Map<string, object> messageParams = (Map<String, Object>)params.get('message');
            messageText = (String)messageParams.get('text');            
        }
                
        //改行を置換
        messageText = messageText.replaceAll('[\n]+','');
        
        //ナレッジ検索
        List<List<KnowledgeArticleVersion>> resultList = [FIND :messageText RETURNING KnowledgeArticleVersion(Id,Title,Summary,UrlName WHERE PublishStatus='online' AND Language= 'ja')];
                                        
        HttpRequest hreq = new HttpRequest();
        hreq.setHeader('Content-Type', 'application/json');
        hreq.setHeader('Authorization', 'Bearer '+ CH_ACCESS_TOKEN);
        hreq.setEndpoint(LINE_REPLY_URI);
        hreq.setMethod('POST');
        
        if(resultList[0].isEmpty()){
            hreq.setBody('{"replyToken":"' +  replyToken  + '" ,"messages":[{"type":"text", "text":"' + messageText + ':該当のナレッジはありません"}]}');
        }else{
            hreq.setBody('{"replyToken":"' +  replyToken  + '" ,"messages":[' + getCarouselTemp(resultList) + ']}');
        }
        
        Http http = new Http();
        HTTPResponse hres; 
        
        try {
            hres = http.send(hreq);
            System.debug('●HTTP Response Code: ' + hres.getStatusCode());
            System.debug('●Response Body: ' + hres.getBody());
         
        } catch (Exception e) {
            System.debug('●Error:' + e.getMessage());            
        }
        
        Map<string, string> result= new Map<String, String>();
        result.put('result', 'success');         
          
        return result;
    }
    
    //カルーセルテンプレート
    private Static String getCarouselTemp(List<List<KnowledgeArticleVersion>> kavList){

        List<Object> colList = new List<Object>();      
        for(KnowledgeArticleVersion objKav : kavList[0]){
            Map<String, Object> cloumnActionMap = new Map<String, Object> {
                'title' => objKav.Title,
                'text' => objKav.Summary,
                'actions' => new Object[] {
                    new Map<String, Object> {
                        'type' => 'uri',
                        'label' => '見る',
                        'uri' => MYSITESURL + objKav.UrlName
                    }
                }
            };
            colList.add(cloumnActionMap);    
        }
        
        Map<String, Object> jMap = new Map<String, Object> {
                'type' => 'template',
                'altText' => 'this is a carousel template',
                'template' => new Map<String, Object>{
                    'type' => 'carousel',
                    'columns' => colList
                } 
            };
                
       return JSON.serialize(jMap); 

    }
     
}