ApexでGCPのVision APIを使ってみた

public with sharing class GCPLogic {
  @Future(callout=true)
  public static void callCloudVisionAPI(String inputFilePass,String outputFolderPass) {

    Http http = new Http();
    HttpRequest req = new HttpRequest();

    //指定ログイン情報で設定した名前を設定する
    String reqPath = 'callout:GCP_visionapi';
    req.setEndpoint(reqPath);
    req.setMethod('POST');
    req.setHeader('content-type', 'application/json');
    //GCPのプロジェクトIDを指定
    req.setHeader('x-goog-project-id', '696775376003');
    //JSONを生成
    JSONGenerator requests = JSON.createGenerator(true);
      
    requests.writeStartObject();
    requests.writeFieldName('requests');
    requests.writeStartArray();
    requests.writeStartObject();
    requests.writeFieldName('inputConfig');
    requests.writeStartObject();
    requests.writeFieldName('gcsSource');
    requests.writeStartObject();
    requests.writeStringField('uri', inputFilePass);
    requests.writeEndObject();
    requests.writeStringField('mimeType', 'application/pdf');
    requests.writeEndObject();
    requests.writeFieldName('features');
    requests.writeStartArray();
    requests.writeStartObject();
    requests.writeStringField('type', 'DOCUMENT_TEXT_DETECTION');
    requests.writeEndObject();
    requests.writeEndArray();
    requests.writeFieldName('outputConfig');
    requests.writeStartObject();
    requests.writeFieldName('gcsDestination');
    requests.writeStartObject();
    requests.writeStringField('uri', outputFolderPass);
    requests.writeEndObject();
    requests.writeNumberField('batchSize', 1);
    requests.writeEndObject();
    requests.writeEndObject();
    requests.writeEndArray();
    requests.writeEndObject();

    String reqBody = requests.getAsString();
    System.debug(reqBody);
    req.setBody(reqBody);

    HttpResponse res = http.send(req);

    if (res.getStatusCode() == 200) {
      Map<String, Object> results = (Map<String, Object>) JSON.deserializeUntyped(res.getBody());
      System.debug('成功：'+results);
    }else {
      Map<String, Object> results = (Map<String, Object>) JSON.deserializeUntyped(res.getBody());
      System.debug('エラー：'+results);
    }
  }
}

{
  "requests": [
    {
      "inputConfig": {
        "gcsSource": {
          "uri": "ストレージのファイルパス"
        },
        "mimeType": "application/pdf"
      },
      "features": [
        {
          "type": "DOCUMENT_TEXT_DETECTION"
        }
      ],
      "outputConfig": {
        "gcsDestination": {
          "uri": "ストレージのフォルダパス"
        },
        "batchSize": 1
      }
    }
  ]
}

GCPLogic.callCloudVisionAPI('gs://orc_sample_input/JA_EG_CertifiedIntegrationArchitectureDesigner_SU20.pdf','gs://orc_sample_output/result/');

public with sharing class OCRJSONFormatClass {
  public InputConfig inputConfig;
  public List<Responses> responses;

  public class InputConfig {
    public GcsSource gcsSource;
    public String mimeType;
  }
  
  public class Responses {
    public FullTextAnnotation fullTextAnnotation;
    public Context context;
  }
  
  public class FullTextAnnotation {
    public List<Pages> pages;
    public String text;
  }

  public class Pages {
    public Property property;
    public Integer width;
    public Integer height;
    public List<Blocks> blocks;
  }
  
  public class Property {
    public List<DetectedLanguages> detectedLanguages;
    public DetectedBreak detectedBreak;
  }

  public class Blocks {
    public Property property;
    public BoundingBox boundingBox;
    public List<Paragraphs> paragraphs;
    public String blockType;
    public String confidence;
  }

  public class DetectedLanguages {
    public String languageCode;
    public Double confidence;
  }

  public class BoundingBox {
    public List<NormalizedVertices> normalizedVertices;
  }

  public class NormalizedVertices {
    public Double x;
    public Double y;
  }

  public class Paragraphs {
    public Property property;
    public BoundingBox boundingBox;
    public List<Words> words;
    public String confidence;
  }

  public class Words {
    public Property property;
    public BoundingBox boundingBox;
    public List<Symbols> symbols;
    public String confidence;
  }

  public class Symbols {
    public Property property;
    public String text;
    public String confidence;
  }

  public class DetectedBreak {
    public String type;
  }

  public class Context {
    public String uri;
    public Integer pageNumber;
  }

  public class GcsSource {
    public String uri;
  }
}

@Future(callout=true)
public static void getOCRResultFileXML(String bucketName,String outputFilePass) {
  Http http = new Http();
  HttpRequest req = new HttpRequest();

  //エンドポイントを指定
  String reqPath = 'callout:GCP_XML_API' + '/' + bucketName + '/' + EncodingUtil.urlEncode(outputFilePass, 'UTF-8');

  req.setEndpoint(reqPath);
  req.setMethod('GET');
  req.setHeader('Content-Type', 'text/xml; charset=UTF-8 ');
  req.setTimeout(120000);

  HttpResponse res = http.send(req);

  if (res.getStatusCode() == 200) {
    //取得したJSONファイルの文字列をJSONクラスのdeserializeStrictで定義した型に並列化する
    OCRJSONFormatClass results = (OCRJSONFormatClass)JSON.deserializeStrict(res.getBody(),OCRJSONFormatClass.class);

    //取得結果をループしてデバッグ表示する
    for(OCRJSONFormatClass.Responses response : results.responses){
      List<String> splitTexts = response.fullTextAnnotation.text.split('\n');
      for(String text : splitTexts){
        System.debug(text);
      }
    }
  }else {
    Map<String, Object> results = (Map<String, Object>) JSON.deserializeUntyped(res.getBody());
    System.debug(results);
  }
}

GCPLogic.getOCRResultFileXML('orc_sample_output','result/output-1-to-1.json');