実際に出会ったエラー「MIXED_DML_OPERATION」の概要と回避策を紹介！

public with sharing class CheckMixedDmlOperation {
    public CheckMixedDmlOperation() {

    }

    public void checkMixedDmlOpe(){

        //ユーザを作成
        User u = createUser();
        insert u;
        System.debug('ユーザを登録しました');

        //権限セットを取得し、ユーザに割り当てる
        PermissionSet ps = [SELECT Id,Name FROM PermissionSet WHERE Name = 'TestPermSet' LIMIT 1];

        PermissionSetAssignment psa = new PermissionSetAssignment();
        psa.AssigneeId = u.Id;
        psa.PermissionSetId = ps.Id;
        insert psa;　//設定オブジェクトのDML操作
        System.debug('権限セットを割り当てました');

        //取引先を作成
        Account acc = createAccount(u.Id);
        insert acc;　//非設定オブジェクトのDML操作
        System.debug('取引先を作成しました');

    }
    //ユーザを作成
    public user createUser(){

        profile Pf = [SELECT Id,name FROM profile WHERE name = '検証用プロファイル' LIMIT 1];

            User u = new User();
            u.ProfileId = pf.Id;
            u.LastName = 'testuser';
            u.Alias = 'testUser';
            u.Email = 'test@xx.xxx.com';
            u.UserName = 'test.y@test.com';
            u.EmailEncodingKey = 'ISO-2022-JP';
            u.LanguageLocaleKey = 'ja';
            u.LocaleSidKey = 'ja_JP';
            u.TimeZoneSidKey = 'Asia/Tokyo';
            return u;
    }

    //取引先を作成
    public Account createAccount(Id uId){
        Account acc = new Account();
        acc.Name = 'test';
        acc.ownerId = uId;
        return acc;
    }
}

public class CheckMixedDmlOperation_Queueable implements Queueable {

    public CheckMixedDmlOperation_Queueable() {
    }

    public void execute(QueueableContext context) {
        System.debug('CheckMixedDmlOperation_Queueable:execute メソッドを開始しました。');

        // プロファイルと権限セットを取得
        Profile Profile = [SELECT Id, Name FROM Profile WHERE Name = '検証用プロファイル' LIMIT 1];
        PermissionSet ps = [SELECT Id, Name FROM PermissionSet WHERE Name = 'testPermSet' LIMIT 1];

        // ユーザの作成
        User u = createUser(Profile.Id);
        insert u;
        System.debug('ユーザが作成されました');

        //権限セットの割り当て
        PermissionSetAssignment psa = new PermissionSetAssignment();
        psa.AssigneeId =u.Id;
        psa.PermissionSetId = ps.Id;
        insert psa;　//設定オブジェクトのDML操作
        System.debug('権限セットを割り当てました');

        //取引先作成のQueueableジョブをキューに入れる
        System.enqueueJob(new CreateAccount_Queueable(u.Id));
        System.debug('CreateAccount_Queueable ジョブをキューに入れました。');
    }

    //ユーザ作成
    private static User createUser(Id profileId) {
        User u = new User();
        u.ProfileId = profileId;
        u.LastName = '検証用ユーザ';
        u.Alias = 'testUser';
        u.Email = 'test@xx.xxx.com';
        u.UserName = 'test.xxx@test.com';
        u.EmailEncodingKey = 'ISO-2022-JP';
        u.LanguageLocaleKey = 'ja';
        u.LocaleSidKey = 'ja_JP';
        u.TimeZoneSidKey = 'Asia/Tokyo';
        return u;
    }
}

public class CreateAccount_Queueable implements Queueable {

    private Id userId;

    public CreateAccount_Queueable(Id userId) {
        this.userId = userId;
    }

    public void execute(QueueableContext context) {
        System.debug('CreateAccount_Queueable:execute メソッドを開始しました。');
        //取引先の作成
        Account acc = new Account();
        acc.Name = '株式会社ABC';
        acc.OwnerId = this.userId;
        insert acc;　//非設定オブジェクトのDML操作
        
        System.debug('取引先が作成されました');

    }
}