Apex一括処理（バッチ処理）のエラーハンドリング方法紹介

    public void execute(Database.BatchableContext bc, List<Account> scope) {
        try {
            Integer sumVal = 0;
            for (Account acc : scope) {
                sumVal += acc.NumberOfEmployees;
            }
        } catch (Exception ex) {
            // catch可能なため、エラーハンドリングが可能
            // カスタムオブジェクトのErrorLogへエラー内容を保存する
            ErrorLog__c errLog = new ErrorLog__c();
            errLog.ErrMessage__c = ex.getMessage();
            errLog.StackTrace__c = ex.getStackTraceString();
            insert errLog;
        }
    }

    public void execute(Database.BatchableContext bc, List<Account> scope) {
        try {
            // ガバナエラー
            for (Integer i=0;i<201;i++) {
                Account test = [select id from Account where id = :scope[0].id];
            }
        } catch (Exception ex) {
            // catchされないため、エラーハンドリングが出来ない
            // カスタムオブジェクトのErrorLogへエラー内容を保存する
            ErrorLog__c errLog = new ErrorLog__c();
            errLog.ErrMessage__c = ex.getMessage();
            errLog.StackTrace__c = ex.getStackTraceString();
            insert errLog;
        }
    }

public with sharing class TestBatch implements Database.Batchable<sObject>, Database.RaisesPlatformEvents {

trigger BatchApexErrorEventTrg on BatchApexErrorEvent (after insert) {
    // エラーハンドリング処理を実装（記載は省略）
}

public with sharing class TestBatch implements Database.Batchable<sObject>, Database.RaisesPlatformEvents {

    public Database.QueryLocator start(Database.BatchableContext bc) {
        return Database.getQueryLocator([SELECT id,name,NumberOfEmployees FROM Account]);
    }

    // エラー発生のテストのため、処理に意味はありません
    public void execute(Database.BatchableContext bc, List<Account> scope) {
        for (Integer i=0;i<201;i++) {
            Account acc = [select id from Account where id = :scope[0].id];
        }
    }

    public void finish(Database.BatchableContext bc) {
        system.debug('TestBatch finish');
    }
}

trigger BatchApexErrorEventTrg on BatchApexErrorEvent (after insert) {
    // 実処理はトリガーハンドラーにて実行する
    BatchApexErrorEventHandler triggerHandler = new BatchApexErrorEventHandler();
    triggerHandler.onAfterInsert(Trigger.new);
}

public with sharing class BatchApexErrorEventHandler {
    private Map<Id, AsyncApexJob> jobMap;
    private Map<Id, ApexClass> classMap;

    public void onAfterInsert(List<BatchApexErrorEvent> newList){
        // Apexクラス名を取得
        getClassInfo(newList);
        // エラーハンドリング
        errorHandler(newList);
    }

    private void getClassInfo(List<BatchApexErrorEvent> errorEventList){
        Set<Id> asyncApexJobIds = new Set<Id>();
        for(BatchApexErrorEvent evt : errorEventList){
            asyncApexJobIds.add(evt.AsyncApexJobId);
        }
        jobMap = new Map<Id, AsyncApexJob>([SELECT Id, ApexClassID FROM AsyncApexJob WHERE Id IN :asyncApexJobIds]);
        Set<Id> classIds = new Set<Id>();
        for(AsyncApexJob job : jobMap.values()){
            classIds.add(job.ApexClassID);
        }
        classMap = new Map<Id, ApexClass>([SELECT Id, Name FROM ApexClass WHERE Id IN :classIds]);
    }

    private void errorHandler(List<BatchApexErrorEvent> errorEventList) {
        // 任意のエラーハンドリングを行う
        // insert用バッチエラーログList
        List<ErrorLog__c> errLogList = new List<ErrorLog__c>();
        for (BatchApexErrorEvent errorEvent: errorEventList) {
            ErrorLog__c errLog = new ErrorLog__c();
            // ApexジョブID
            errLog.AsyncApexJobId__c = errorEvent.AsyncApexJobId;
            // Apexクラス名
            errLog.ApexClassName__c = classMap.get(jobMap.get(errorEvent.AsyncApexJobId).ApexClassID).Name;
            // 例外種別名
            errLog.ExceptionType__c = errorEvent.ExceptionType;
            // スコープ
            errLog.JobScope__c = errorEvent.JobScope;
            // エラーメッセージ
            errLog.ErrMessage__c = errorEvent.Message;
            // 発生フェーズ
            errLog.Phase__c = errorEvent.Phase;
            // リプレイID
            errLog.ReplayId__c = errorEvent.ReplayId;
            // スタックトレース
            errLog.StackTrace__c = errorEvent.StackTrace;
            // insert用Listに格納
            errLogList.add(errLog);
        }
        // insert
        if (errLogList.size() > 0) {
            insert errLogList;
        }
    }
}