パッケージ開発をしよう！ 保護されたカスタムメタデータの活用

global class ProtectedCustomMetadata {
    global String label = null;
    global String developerName = null;
    global String protectedField = null;

    global ProtectedCustomMetadata() {
    }
    global ProtectedCustomMetadata(String label, String name, String text) {
        this.label = label;
        this.developerName = name;
        this.protectedField = text;
    }
    global ProtectedCustomMetadata(ProtectedCustomMetadata__mdt record) {
        this.label = record.label;
        this.developerName = record.DeveloperName;
        this.protectedField = record.ProtectedField__c;
    }
}

global with sharing class CustomMetadataService {
    /* 
     * developerNameを指定してレコードを取得するメソッド
     * 戻り値はパッケージ内でglobalに宣言したラッパークラス
     */
    global ProtectedCustomMetadata get(String developerName) {
        ProtectedCustomMetadata__mdt[] records = [
            select Id
                 , label
                 , DeveloperName
                 , ProtectedField__c
              from ProtectedCustomMetadata__mdt
             where DeveloperName = :developerName
        ];
        if (records.size() == 0) {
            return null;
        }
        return new ProtectedCustomMetadata(records[0]);
    }

    /* 
     * 全レコードを取得するメソッド
     * 戻り値はパッケージ内でglobalに宣言したラッパークラスの配列
     */
    global ProtectedCustomMetadata[] getAll() {
        ProtectedCustomMetadata__mdt[] records = [
            select Id
                 , label
                 , DeveloperName
                 , ProtectedField__c
              from ProtectedCustomMetadata__mdt
        ];
        ProtectedCustomMetadata[] metadataList = new ProtectedCustomMetadata[0];
        for (ProtectedCustomMetadata__mdt record : records) {
            metadataList.add(new ProtectedCustomMetadata(record));
        }
        return metadataList;
    }
    
    /* 
     * パッケージ内でglobalに宣言したラッパークラスを受け取り
     * 保護されたカスタムメタデータのレコードを作成するメソッド
     * 
     * 実際にデプロイする処理はテストクラスでテストできないため、別メソッドとして分離する。
     */
    global Id deploy(ProtectedCustomMetadata customMeta) {
        Metadata.DeployContainer container = createDeployContainer(customMeta);
        return Metadata.Operations.enqueueDeployment(container , null);
    }
    
    /* 
     * パッケージ内でglobalに宣言したラッパークラスを受け取り
     * 保護されたカスタムメタデータのレコードを作成するメソッド
     * 
     * デプロイ処理はテストクラスで実行できないため、デプロイするメタデータの作成処理を別メソッドとして分離する。
     * テストクラスでは本メソッドの戻り値から含まれるメタデータを取得して比較する。
     * 例)
     * Metadata.DeployContainer container = service.createDeployContainer(customMeta);
     * Metadata.Metadata[] contents = container.getMetadata();
     * System.assertEquals(1, contents.size());
     */
    @TestVisible
    private Metadata.DeployContainer createDeployContainer(ProtectedCustomMetadata customMeta) {
        Metadata.CustomMetadata customMetadata = new Metadata.CustomMetadata();
        customMetadata.fullName = 'SuzukiExample__ProtectedCustomMetadata__mdt.' + customMeta.DeveloperName;
        customMetadata.label = customMeta.label;

        Metadata.CustomMetadataValue field = new Metadata.CustomMetadataValue();
        field.field = 'SuzukiExample__ProtectedField__c';
        field.value = customMeta.protectedField;
        customMetadata.values.add(field);

        Metadata.DeployContainer container = new Metadata.DeployContainer();
        container.addMetadata(customMetadata);
        return container;
    }
}

System.debug([
    select Id 
      from SuzukiExample__ProtectedCustomMetadata__mdt
]);

SuzukiExample.ProtectedCustomMetadata customMeta
    = new SuzukiExample.ProtectedCustomMetadata('TestCustomMeta', 'TestCustomMeta', 'TestField');
SuzukiExample.CustomMetadataService service = new SuzukiExample.CustomMetadataService();
service.deploy(customMeta);

SuzukiExample.CustomMetadataService service = new SuzukiExample.CustomMetadataService();
System.debug(service.getAll());