Einstein ボットからApexクラスを呼び出す方法について

public with sharing class EinsteinChatbots_SearchFAQ {
   //ボット設定画面の入力値
   public class FAQSearchInput{
       @InvocableVariable(required=true)
       public String category;
   }
   
   //ボット設定画面の出力値
   public class FAQSearchOutput{
       @InvocableVariable(required=true) 
       public List<Knowledge__kav> botOutputList;
   }
   
   //ボット設定画面から呼び出し
   @InvocableMethod(label='Einstein Chatbots - Search FAQ')
   public static List<FAQSearchOutput> searchFAQ(List<FAQSearchInput> faqSearchInput){
       //ボット設定画面で入力した値を変数へ設定
       String category = faqSearchInput[0].category;
       
       //対象カテゴリの公開済みナレッジを取得
       String KnowledgeKavString = 'SELECT Id, Title, Naiyou__c'
                                 + ' FROM Knowledge__kav'
                                 + ' WHERE PublishStatus = \'Online\''
                                 + ' AND Language = \'ja\''
                                 + ' WITH DATA CATEGORY Cloud__c'
                                 + ' ABOVE_OR_BELOW ' + category
                                 + ' ORDER BY ArticleTotalViewCount DESC'
                                 + ' LIMIT 5';
       List<Knowledge__kav> KnowledgeKavList;
       try {
           KnowledgeKavList = Database.query(KnowledgeKavString);
       } catch(QueryException e) {
           System.debug('次の例外が発生しました: ' + e.getMessage());
           return null;
       }
       
       //ナレッジのリストをボット設定画面へ出力
       List<FAQSearchOutput> faqSearchOutputs = new List<FAQSearchOutput>();
       FAQSearchOutput faqSearchOutput = new FAQSearchOutput();
       faqSearchOutput.botOutputList = KnowledgeKavList;
       faqSearchOutputs.add(faqSearchOutput);
       return faqSearchOutputs;
   }
}