Agentforce × Prompt Builder × Apexで構築する、連動選択リスト対応のCaseカテゴリー自動分類フロー

public class DepPickListCtrl {
        
    @InvocableMethod
    //フローから呼び出されるメソッド
    //オブジェクト名、項目名、親カテゴリーの値が渡されてくる
    public static List<String> getDependentOptionsForPrompt(List<DependencyRequest> requests){
        List<String> results = new List<String>();
        for(DependencyRequest req: requests){
            results.add(generateDependencyString(req.ObjName,req.ControllingFieldName,req.DependentFieldName,req.selectedParentLabel));
        }
        return results;
    }
    
    public class DependencyRequest{
        @InvocableVariable(required=true) public String ObjName; //オブジェクト名
        @InvocableVariable(required=true) public String ControllingFieldName; //親となるカテゴリー
        @InvocableVariable(required=true) public String DependentFieldName;   //子となるカテゴリー
        @InvocableVariable(required=true) public String selectedParentLabel;  //親カテゴリーの値
    }
    
    public static String generateDependencyString(String ObjName,String ControllongFieldName,String DependentFieldName,String parentLabel){
        //組織内のオブジェクト情報を取得する
        Schema.SObjectType targetType = Schema.getGlobalDescribe().get(ObjName); 
        Map<String, Schema.SObjectField> fieldMap = targetType.getDescribe().fields.getMap();
        
        // 子項目のメタデータを取得
        Schema.DescribeFieldResult controllerFieldDesc = fieldMap.get(ControllongFieldName).getDescribe();
        Schema.DescribeFieldResult dependentFieldDesc  = fieldMap.get(DependentFieldName).getDescribe();
                
        // 親の選択肢リストから、選ばれたラベルが何番目（インデックス）かを探す
        Integer parentIndex = -1;
        List<Schema.PicklistEntry> controllerValues = controllerFieldDesc.getPicklistValues();
        System.debug(controllerValues);
        for (Integer i = 0; i < controllerValues.size(); i++) {
            if (controllerValues[i].getLabel() == parentLabel) {
                parentIndex = i;
                break;
            }
        }
        
        System.debug('parentIndex：'+ parentIndex);
        if (parentIndex == -1) {
            return null;
        }
        
        // 子の選択肢をループして、親インデックスに対応するものだけを抽出
        List<String> validChildren = new List<String>();
        for (Schema.PicklistEntry entry : dependentFieldDesc.getPicklistValues()) {
            if (isChildValidForParent(entry, parentIndex)) {
                validChildren.add(entry.getLabel());
            }
        }  
        
        if (validChildren.isEmpty()) {
            System.debug('ValidChildrenがEmpty');
            return null;
        }
        
        return String.join(validChildren, ', ');
    }
    
    private static Boolean isChildValidForParent(Schema.PicklistEntry entry, Integer parentIndex) {
        // validForの中身を取得するために一度JSONシリアライズ
        String jsonEntry = JSON.serialize(entry);
        Map<String, Object> entryMap = (Map<String, Object>) JSON.deserializeUntyped(jsonEntry);
        String validFor = (String) entryMap.get('validFor');

        if (String.isBlank(validFor)) return true; // 連動設定がない場合は常に有効

        // Base64をビット列に変換し、parentIndexの位置が '1' かどうかをチェック
        List<Integer> validIndices = getValidParentIndices(validFor);
        return validIndices.contains(parentIndex);
    }
    
    // Base64ビットマップをインデックス番号のリストに変換
    private static List<Integer> getValidParentIndices(String validFor) {
        List<Integer> indices = new List<Integer>();
        String hex = '';
        String base64Chars = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/';
        
        for (Integer i = 0; i < validFor.length(); i++) {
            Integer val = base64Chars.indexOf(validFor.substring(i, i + 1));
            String bin = '';
            for (Integer j = 0; j < 6; j++) {
                bin = (Math.mod(val, 2) == 0 ? '0' : '1') + bin;
                val /= 2;
            }
            hex += bin;
        }

        for (Integer i = 0; i < hex.length(); i++) {
            if (hex.substring(i, i + 1) == '1') {
                indices.add(i);
            }
        }
        return indices;      
    }
    
}